19 mai 10 Envoyer le contenu d’un fichier par mail en batch

Ce n’est pas la première fois que j’ai à coder rapidement un petit fichier .bat pour exécuter des commandes automatiquement. Aujourd’hui, j’avais besoin d’un petit script envoyant le contenu du fichier de log le plus récent d’un répertoire sur un serveur sous Windows Server 2003 par email.

Sous linux, poster un mail, pas de problème. Sous windows j’avais encore jamais essayé et je redoutais le « il faut acheter tel module, ça fera tant etc.« … Mais en fait non, grace à un petit executable open source appellé Blat !

Blat est un petit executable utilisable en ligne de commandes ultra léger proposant des fonctions relativement simples d’utilisation. (voir ici pour sa syntaxe ou encore là pour les exemples).

J’avais le programme pour envoyer les mails, il ne manquait plus que le petit script qui va bien pour récupérer le dernier fichier .log du répertoire et lancer la commande d’envoi de mail.

Le script

@echo off

set repertoire="C:\Mon repertoire\"
set emetteur=email.emmeteur@domaine.com
set eMail=email.destinataireg@domaine.com
set copie=-cc destinataire.copie@domaine.com
set subj=-s "Titre de mon message"
set server=-server smtp.domaine.com
set x=-x "X-Header-Test: header supplémentaire optionnel inséré dans le mail"
set debug=-debug -log envois-mails.log -timestamp

FOR /F "tokens=*" %%i IN ('DIR /B /O-D %repertoire%*.log') DO set fichier="%repertoire:"=%%%i" && GOTO DONE || GOTO DONE
: DONE

blat %fichier% -mime -8bitmime -to %eMail% %copie% -f %emetteur% %subj% %server% %debug% %x%

Détail du code

set repertoire="C:\Mon repertoire\"

Pas trop compliqué, on indique le chemin absolu vers le répertoire. Ne pas oublier l’anti slash à la fin, il sert ensuite pour la construction de l’adresse du fichier.

set emetteur=email.emmeteur@domaine.com

L’adresse email qui enverra le message

set eMail=email.destinataireg@domaine.com

L’adresse email qui recevra le message

set copie=-cc destinataire.copie@domaine.com

L’adresse email qui recevra le message en copie. A noter que l’option est présente aussi dans la variable. Si l’on ne veux pas de copie il suffit de remplacer cette ligne par :
set copie=

set subj=-s "Titre de mon message"

Le sujet du message expédié

set server=-server smtp.domaine.com

On précise quel serveur servira de serveur d’envoi de mail. J’avais mis le serveur d’envoi de mail de la société qui m’emploi, on peut très bien mettre le smtp de son FAI si on veux (smtp.orange.fr par exemple)

set x=-x "X-Header-Test: header supplémentaire optionnel inséré dans le mail"

On peut préciser des entetes personnalisés au mail via l’option -x. Celui là ne sert à rien, il est juste présent en démonstration. Si on ne veux rien mettre, remplacer cette ligne par :
set x=

set debug=-debug -log envois-mails.log -timestamp

Blat permet de gérer son propre log. Pratique en cas de debug. Ici, il génèrera un fichier « envois-mails.log » si celui-ci n’est pas présent ou rajoutera des lignes en fin de fichier si celui-ci existe déjà. (un log quoi )

FOR /F "tokens=*" %%i IN ('DIR /B /O-D %repertoire%*.log') DO set fichier="%repertoire:"=%%%i" && GOTO DONE || GOTO DONE
: DONE 

Cette ligne était la plus importante pour moi.
On fait défiler le fichiers .log du répertoire en les ordinant du plus récent au plus ancien. Une fois qu’on a récupéré le nom du premier de la liste, on génère une variable « fichier » contenant la concaténation de la variable « %repertoire% » et de la variable « %%i » et on sort de la boucle.
Petite note sur la concaténation : Normalement, pour concaténer, il suffit d’utiliser cette syntaxe :

%var1%%var2% 

Là mon soucis c’est que le répertoire peut contenir des espaces dans son chemin (par exemple : « Documents and settings »). J’étais donc obligé d’encadrer le contenu de la variable %repertoire% avec des doubles quotes. Le problème que j’avais en faisant un simple %repertoire%%%i c’est que ça me ressortait systématiquement (et logiquement) un contenu de variable comme cela :

"C:\Mon repertoire\"fichier.log

J’ai donc utilisé cette syntaxe :

%repertoire:"=%

Syntaxe qui correspondrait à un str_replace() en PHP. Ici en l’occurence, je remplace les doubles quotes de ma variable par un vide, je les efface donc.
Donc, en faisant un :

set fichier="%repertoire:"=%%%i"

J’obtiens un retour propre avec doubles quotes au bon endroit :

"C:\Mon repertoire\fichier.log"

Enfin, la dernière commande du fichier :

blat %fichier% -mime -8bitmime -to %eMail% %copie% -f %emetteur% %subj% %server% %debug% %x%

La commande appelle l’executable « blat » qui est présent dans le même répertoire que mon .bat (sinon il aurait fallu mettre C:\mon-repertoire\blat.exe) et lui passe les différentes variables en paramètres ce qui provoque l’envoi du mail.

Mise à jour :
J’ai remarqué après avoir posté ce billet que les emails arrivaient avec un encodage de caractères particulier, l’UTF-7.
Sur mon Outlook 2007 je n’observais aucun problème. C’est un collègue lisant ses mails via gmail qui était envoyé en copie qui m’a remonté que ses mails étaient illisibles.
Après « un peu » de recherche et de tests (une heure quoi ^^) j’ai fini par trouver qu’il fallait ajouter les options « -mime » et « -8bitmime » dans la commande « blat » pour que l’entête de l’email passe de :

Content-Type: text/plain; charset=UTF-7

à celui là plus conventionnel :

Content-Type: text/plain; charset=UTF-8

L’encodage UTF-8 (unicode) est beaucoup plus conventionnel, surtout aux yeux de Gmail

Télécharger

J’ai mis les sources à disposition dans cette archive pour les flemmards qui veulent tester rapidement.
Batch d’envoi de contenu de fichier par mail

Voilou, ce fut plus long a expliquer qu’a coder

• Tweet
• "&title=""">